%{
#if __GNUC__ >= 7
_Pragma("GCC diagnostic ignored \"-Wimplicit-fallthrough\"")
#endif
#include <stddef.h>
#include "conf-parser.h"
#include "ethtool-util.h"
#include "link-config.h"
#include "network-internal.h"
%}
struct ConfigPerfItem;
%null_strings
%language=ANSI-C
%define slot-name section_and_lvalue
%define hash-function-name link_config_gperf_hash
%define lookup-function-name link_config_gperf_lookup
%readonly-tables
%omit-struct-type
%struct-type
%includes
%%
Match.MACAddress,                config_parse_hwaddrs,                  0,                             offsetof(link_config, match_mac)
Match.PermanentMACAddress,       config_parse_hwaddrs,                  0,                             offsetof(link_config, match_permanent_mac)
Match.OriginalName,              config_parse_match_ifnames,            0,                             offsetof(link_config, match_name)
Match.Path,                      config_parse_match_strv,               0,                             offsetof(link_config, match_path)
Match.Driver,                    config_parse_match_strv,               0,                             offsetof(link_config, match_driver)
Match.Type,                      config_parse_match_strv,               0,                             offsetof(link_config, match_type)
Match.Property,                  config_parse_match_property,           0,                             offsetof(link_config, match_property)
Match.Host,                      config_parse_net_condition,            CONDITION_HOST,                offsetof(link_config, conditions)
Match.Virtualization,            config_parse_net_condition,            CONDITION_VIRTUALIZATION,      offsetof(link_config, conditions)
Match.KernelCommandLine,         config_parse_net_condition,            CONDITION_KERNEL_COMMAND_LINE, offsetof(link_config, conditions)
Match.KernelVersion,             config_parse_net_condition,            CONDITION_KERNEL_VERSION,      offsetof(link_config, conditions)
Match.Architecture,              config_parse_net_condition,            CONDITION_ARCHITECTURE,        offsetof(link_config, conditions)
Link.Description,                config_parse_string,                   0,                             offsetof(link_config, description)
Link.MACAddressPolicy,           config_parse_mac_address_policy,       0,                             offsetof(link_config, mac_address_policy)
Link.MACAddress,                 config_parse_hwaddr,                   0,                             offsetof(link_config, mac)
Link.NamePolicy,                 config_parse_name_policy,              0,                             offsetof(link_config, name_policy)
Link.Name,                       config_parse_ifname,                   0,                             offsetof(link_config, name)
Link.AlternativeName,            config_parse_ifnames,                  1,                             offsetof(link_config, alternative_names)
Link.AlternativeNamesPolicy,     config_parse_alternative_names_policy, 0,                             offsetof(link_config, alternative_names_policy)
Link.Alias,                      config_parse_ifalias,                  0,                             offsetof(link_config, alias)
Link.MTUBytes,                   config_parse_mtu,                      AF_UNSPEC,                     offsetof(link_config, mtu)
Link.BitsPerSecond,              config_parse_si_uint64,                0,                             offsetof(link_config, speed)
Link.Duplex,                     config_parse_duplex,                   0,                             offsetof(link_config, duplex)
Link.AutoNegotiation,            config_parse_tristate,                 0,                             offsetof(link_config, autonegotiation)
Link.WakeOnLan,                  config_parse_wol,                      0,                             offsetof(link_config, wol)
Link.Port,                       config_parse_port,                     0,                             offsetof(link_config, port)
Link.ReceiveChecksumOffload,     config_parse_tristate,                 0,                             offsetof(link_config, features[NET_DEV_FEAT_RX])
Link.TransmitChecksumOffload,    config_parse_tristate,                 0,                             offsetof(link_config, features[NET_DEV_FEAT_TX])
Link.GenericSegmentationOffload, config_parse_tristate,                 0,                             offsetof(link_config, features[NET_DEV_FEAT_GSO])
Link.TCPSegmentationOffload,     config_parse_tristate,                 0,                             offsetof(link_config, features[NET_DEV_FEAT_TSO])
Link.TCP6SegmentationOffload,    config_parse_tristate,                 0,                             offsetof(link_config, features[NET_DEV_FEAT_TSO6])
Link.UDPSegmentationOffload,     config_parse_warn_compat,              DISABLED_LEGACY,               0
Link.GenericReceiveOffload,      config_parse_tristate,                 0,                             offsetof(link_config, features[NET_DEV_FEAT_GRO])
Link.LargeReceiveOffload,        config_parse_tristate,                 0,                             offsetof(link_config, features[NET_DEV_FEAT_LRO])
Link.RxChannels,                 config_parse_channel,                  0,                             offsetof(link_config, channels)
Link.TxChannels,                 config_parse_channel,                  0,                             offsetof(link_config, channels)
Link.OtherChannels,              config_parse_channel,                  0,                             offsetof(link_config, channels)
Link.CombinedChannels,           config_parse_channel,                  0,                             offsetof(link_config, channels)
Link.Advertise,                  config_parse_advertise,                0,                             offsetof(link_config, advertise)
Link.RxBufferSize,               config_parse_nic_buffer_size,          0,                             offsetof(link_config, ring)
Link.TxBufferSize,               config_parse_nic_buffer_size,          0,                             offsetof(link_config, ring)
