#############################################################################################
### ${CTEST_SCRIPT_ARG} is of the form OPTION=VALUE                                       ###
### BUILD_GENERATOR required [Unix, VS2022, VS202264, VS2019, VS201964]                   ###
### ctest -S HDF4config.cmake,BUILD_GENERATOR=VS201764 -C Release -VV -O hdf4.log         ###
#############################################################################################

cmake_minimum_required (VERSION 3.18)
############################################################################
# Usage:
#     ctest -S HDF4config.cmake,OPTION=VALUE -C Release -VV -O test.log
# where valid options for OPTION are:
#     NINJA           - Use Ninja build system
#     BUILD_GENERATOR - The cmake build generator:
#            MinGW     * MinGW Makefiles
#            Unix      * Unix Makefiles
#            VS2022    * Visual Studio 17 2022
#            VS202264  * Visual Studio 17 2022
#            VS2019    * Visual Studio 16 2019
#            VS201964  * Visual Studio 16 2019
#            VS2017    * Visual Studio 15 2017
#            VS201764  * Visual Studio 15 2017 Win64
#            VS2015    * Visual Studio 14 2015
#            VS201564  * Visual Studio 14 2015 Win64
#
#     INSTALLDIR  -  root folder where hdf is installed
#                 -  windowsdefault: C:/Program Files/HDF_Group/HDF/4.2.15
#                 -  linux default:  ./HDF_Group/HDF/4.2.15
#     CTEST_CONFIGURATION_TYPE  - Release, Debug, etc - default: Release
#     CTEST_SOURCE_NAME  -  source folder - default: hdf4
#     STATIC_ONLY  -  Build/use static libraries
#     FORTRAN_LIBRARIES -  Build/use fortran libraries
#     NO_MAC_FORTRAN  - Yes to be SHARED on a Mac
##############################################################################

set (CTEST_SOURCE_VERSION "4.3.1")
set (CTEST_SOURCE_VERSEXT "")

##############################################################################
# handle input parameters to script.
#BUILD_GENERATOR - which CMake generator to use, required
#INSTALLDIR - HDF-4.3.x root folder
#CTEST_CONFIGURATION_TYPE - Release, Debug, RelWithDebInfo
#CTEST_SOURCE_NAME - name of source folder; HDF-4.3.x
#STATIC_ONLY - Default is YES
#FORTRAN_LIBRARIES - Default is NO
#NO_MAC_FORTRAN - set to TRUE to allow shared libs on a Mac
if (DEFINED CTEST_SCRIPT_ARG)
    # transform ctest script arguments of the form
    # script.ctest,var1=value1,var2=value2
    # to variables with the respective names set to the respective values
    string (REPLACE "," ";" script_args "${CTEST_SCRIPT_ARG}")
    foreach (current_var ${script_args})
        if ("${current_var}" MATCHES "^([^=]+)=(.+)$")
            set ("${CMAKE_MATCH_1}" "${CMAKE_MATCH_2}")
        endif ()
    endforeach ()
endif ()

#HPC - run alternate configurations for HPC machines
if (DEFINED HPC)
  set (BUILD_GENERATOR "Unix")
endif ()

# build generator must be defined
if (NOT DEFINED BUILD_GENERATOR)
  message (FATAL_ERROR "BUILD_GENERATOR must be defined - Unix, VS2022, VS202264, VS2019, VS201964")
endif ()

###################################################################
### Following Line is one of [Release, RelWithDebInfo, Debug] #####
###        (default use command line -C value)
set (CTEST_CONFIGURATION_TYPE "$ENV{CMAKE_CONFIG_TYPE}")
###################################################################

if (NOT DEFINED INSTALLDIR)
  if (WIN32)
    set (INSTALLDIR "%ProgramFiles%/HDF_Group/HDF/${CTEST_SOURCE_VERSION}")
  else ()
    set (INSTALLDIR "${CTEST_SCRIPT_DIRECTORY}/HDF_Group/HDF/${CTEST_SOURCE_VERSION}")
  endif ()
endif ()
if (NOT DEFINED CTEST_CONFIGURATION_TYPE)
  set (CTEST_CONFIGURATION_TYPE "Release")
endif ()
if (NOT DEFINED CTEST_SOURCE_NAME)
  set (CTEST_SOURCE_NAME "hdf-${CTEST_SOURCE_VERSION}${CTEST_SOURCE_VERSEXT}")
endif ()
if (NOT DEFINED STATIC_ONLY)
  set (STATICONLYLIBRARIES "YES")
else ()
  set (STATICONLYLIBRARIES "NO")
endif ()
if (NOT DEFINED FORTRAN_LIBRARIES)
  set (FORTRANLIBRARIES "NO")
else ()
  set(FORTRANLIBRARIES "YES")
endif ()

set (CTEST_BINARY_NAME "build")
set (CTEST_DASHBOARD_ROOT "${CTEST_SCRIPT_DIRECTORY}")
if (WIN32 AND NOT MINGW)
  set (CTEST_SOURCE_DIRECTORY "${CTEST_DASHBOARD_ROOT}\\${CTEST_SOURCE_NAME}")
  set (CTEST_BINARY_DIRECTORY "${CTEST_DASHBOARD_ROOT}\\${CTEST_BINARY_NAME}")
else ()
  set (CTEST_SOURCE_DIRECTORY "${CTEST_DASHBOARD_ROOT}/${CTEST_SOURCE_NAME}")
  set (CTEST_BINARY_DIRECTORY "${CTEST_DASHBOARD_ROOT}/${CTEST_BINARY_NAME}")
endif ()

###################################################################
#########       Following describes compiler           ############
if (WIN32 AND NOT MINGW)
  set (SITE_OS_NAME "Windows")
  set (SITE_OS_VERSION "WIN10")
  if (BUILD_GENERATOR STREQUAL "VS202264")
    if (DEFINED NINJA)
      set (CTEST_CMAKE_GENERATOR "Ninja")
    else ()
      set (CTEST_CMAKE_GENERATOR "Visual Studio 17 2022")
      set (CMAKE_GENERATOR_ARCHITECTURE "x64")
    endif ()
    set (SITE_OS_BITS "64")
    set (SITE_COMPILER_NAME "vs2022")
    set (SITE_COMPILER_VERSION "17")
  elseif (BUILD_GENERATOR STREQUAL "VS2022")
    if (DEFINED NINJA)
      set (CTEST_CMAKE_GENERATOR "Ninja")
    else ()
      set (CTEST_CMAKE_GENERATOR "Visual Studio 17 2022")
      set (CMAKE_GENERATOR_ARCHITECTURE "Win32")
    endif ()
    set (SITE_OS_BITS "32")
    set (SITE_COMPILER_NAME "vs2022")
    set (SITE_COMPILER_VERSION "17")
  elseif (BUILD_GENERATOR STREQUAL "VS201964")
    if (DEFINED NINJA)
      set (CTEST_CMAKE_GENERATOR "Ninja")
    else ()
      set (CTEST_CMAKE_GENERATOR "Visual Studio 16 2019")
      set (CMAKE_GENERATOR_ARCHITECTURE "x64")
    endif ()
    set (SITE_OS_BITS "64")
    set (SITE_COMPILER_NAME "vs2019")
    set (SITE_COMPILER_VERSION "16")
  elseif (BUILD_GENERATOR STREQUAL "VS2019")
    if (DEFINED NINJA)
      set (CTEST_CMAKE_GENERATOR "Ninja")
    else ()
      set (CTEST_CMAKE_GENERATOR "Visual Studio 16 2019")
      set (CMAKE_GENERATOR_ARCHITECTURE "Win32")
    endif ()
    set (SITE_OS_BITS "32")
    set (SITE_COMPILER_NAME "vs2019")
    set (SITE_COMPILER_VERSION "16")
  elseif (BUILD_GENERATOR STREQUAL "VS201764")
    if (DEFINED NINJA)
      set (CTEST_CMAKE_GENERATOR "Ninja")
    else ()
      set (CTEST_CMAKE_GENERATOR "Visual Studio 15 2017 Win64")
    endif ()
    set (SITE_OS_BITS "64")
    set (SITE_COMPILER_NAME "vs2017")
    set (SITE_COMPILER_VERSION "15")
  elseif (BUILD_GENERATOR STREQUAL "VS2017")
    if (DEFINED NINJA)
      set (CTEST_CMAKE_GENERATOR "Ninja")
    else ()
      set (CTEST_CMAKE_GENERATOR "Visual Studio 15 2017")
    endif ()
    set (SITE_OS_BITS "32")
    set (SITE_COMPILER_NAME "vs2017")
    set (SITE_COMPILER_VERSION "15")
  else ()
    message (FATAL_ERROR "Invalid BUILD_GENERATOR must be - Unix, VS2022, VS202264, VS2019, VS201964")
  endif ()
##  Set the following to unique id your computer  ##
  if(NOT DEFINED CTEST_SITE)
    set (CTEST_SITE "WIN10${BUILD_GENERATOR}-${CTEST_SITE_EXT}")
  endif()
else ()
  if (DEFINED NINJA)
    set (CTEST_CMAKE_GENERATOR "Ninja")
  else ()
    if (MINGW)
      set (CTEST_CMAKE_GENERATOR "MinGW Makefiles")
    else ()
      set (CTEST_CMAKE_GENERATOR "Unix Makefiles")
    endif ()
  endif ()
##  Set the following to unique id your computer  ##
  if (APPLE)
    if(NOT DEFINED CTEST_SITE)
      set (CTEST_SITE "MAC-${CTEST_SITE_EXT}")
    endif()
  else ()
    if(NOT DEFINED CTEST_SITE)
      set (CTEST_SITE "LINUX-${CTEST_SITE_EXT}")
    endif()
  endif ()
  if (APPLE)
    execute_process (COMMAND xcrun --find cc OUTPUT_VARIABLE XCODE_CC OUTPUT_STRIP_TRAILING_WHITESPACE)
    set (ENV{CC} "${XCODE_CC}")
    set (CTEST_USE_LAUNCHERS        1)
  endif ()
endif ()

###################################################################

###################################################################
#####       Following controls CDash submission               #####
#set (LOCAL_SUBMIT "TRUE")
#####       Following controls test process                   #####
#set (LOCAL_SKIP_TEST "TRUE")
#set (LOCAL_MEMCHECK_TEST "TRUE")
#set (LOCAL_COVERAGE_TEST "TRUE")
#####       Following controls cpack command                  #####
#set (LOCAL_NO_PACKAGE "TRUE")
#####       Following controls source update                  #####
#set (LOCAL_UPDATE "TRUE")
set (REPOSITORY_URL "https://github.com/HDFGroup/hdf4.git")
set (REPOSITORY_BRANCH "hdf4_3_0")

#uncomment to use a compressed source file: *.tar on linux or mac *.zip on windows
#set(CTEST_USE_TAR_SOURCE "${CTEST_SOURCE_VERSION}")
###################################################################


###################################################################

if (WIN32 AND NOT MINGW)
  set (BINFILEBASE "HDF-${CTEST_SOURCE_VERSION}${CTEST_SOURCE_VERSEXT}-win${SITE_OS_BITS}")
  include (${CTEST_SCRIPT_DIRECTORY}\\HDF4options.cmake)
  include (${CTEST_SCRIPT_DIRECTORY}\\CTestScript.cmake)
  if (EXISTS "${CTEST_BINARY_DIRECTORY}\\${BINFILEBASE}.exe")
    file (COPY "${CTEST_BINARY_DIRECTORY}\\${BINFILEBASE}.exe" DESTINATION ${CTEST_SCRIPT_DIRECTORY})
  endif ()
  if (EXISTS "${CTEST_BINARY_DIRECTORY}\\${BINFILEBASE}.msi")
    file (COPY "${CTEST_BINARY_DIRECTORY}\\${BINFILEBASE}.msi" DESTINATION  ${CTEST_SCRIPT_DIRECTORY})
  endif ()
  if (EXISTS "${CTEST_BINARY_DIRECTORY}\\${BINFILEBASE}.zip")
    file (COPY "${CTEST_BINARY_DIRECTORY}\\${BINFILEBASE}.zip" DESTINATION  ${CTEST_SCRIPT_DIRECTORY})
  endif ()
else ()
  set (BINFILEBASE "HDF-${CTEST_SOURCE_VERSION}${CTEST_SOURCE_VERSEXT}")
  include (${CTEST_SCRIPT_DIRECTORY}/HDF4options.cmake)
  include (${CTEST_SCRIPT_DIRECTORY}/CTestScript.cmake)
  if (APPLE)
    if (EXISTS "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Darwin.dmg")
      file (COPY "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Darwin.dmg" DESTINATION ${CTEST_SCRIPT_DIRECTORY})
    endif ()
    if (EXISTS "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Darwin.tar.gz")
      file (COPY "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Darwin.tar.gz" DESTINATION  ${CTEST_SCRIPT_DIRECTORY})
    endif ()
    if (EXISTS "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Darwin.sh")
      file (COPY "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Darwin.sh" DESTINATION ${CTEST_SCRIPT_DIRECTORY})
    endif ()
  else ()
    if (CYGWIN)
      if (EXISTS "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-CYGWIN.sh")
        file (COPY "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-CYGWIN.sh" DESTINATION ${CTEST_SCRIPT_DIRECTORY})
      endif ()
      if (EXISTS "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-CYGWIN.tar.gz")
        file (COPY "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-CYGWIN.tar.gz" DESTINATION  ${CTEST_SCRIPT_DIRECTORY})
      endif ()
    else ()
      if (EXISTS "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Linux.sh")
        file (COPY "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Linux.sh" DESTINATION ${CTEST_SCRIPT_DIRECTORY})
      endif ()
      if (EXISTS "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Linux.tar.gz")
        file (COPY "${CTEST_BINARY_DIRECTORY}/${BINFILEBASE}-Linux.tar.gz" DESTINATION  ${CTEST_SCRIPT_DIRECTORY})
      endif ()
    endif ()
  endif ()
endif ()
